# Model statement for the Nevada Test Site Thyroid Disease Study
# sigmasqB   = Berkson variance			
# sigmasqC   = classical variance		(not passed here, because not used)
# tauB       = 1 / sigmasqB	
# tauC       = 1 / sigmasqC	
# L[i]       = Latent intermediate
# W[i]       = log(geometric mean)
# X[i]       = Latent X
# Age[i]     = Age
# stratum[i] = stratum
# alpha      = mean     of the latent intermediate for the 5 strata
# gamma      = variance of the latent intermediate for the 5 strata


model
{
for (i in 1:Nobservations)
	{
	#Outcome model
	Y[i]~dbern(pY[i])
	logit(pY[i])<-beta[1]+beta[2]*Sex[i]+beta[3]*Age[i] +  
                              log(1+beta[4]*exp(X[i] + (0 * sigmasqB[i]/2)) )
	
	#Exposure model
      L[i]~dnorm(alpha[stratum[i]],gamma[stratum[i]])
	X[i]~dnorm(L[i],tauB[i])
      W[i]~dnorm(L[i],tauC[i])
	}


for (k in 1:5) {gamma[k]~dgamma(0.01,0.01) }            # Prior distribution for the inverse of the variance of L
for (k in 1:5) {alpha[k]~dnorm(0,1.0E-6)}         
beta[1]~dnorm(0,1.0E-6)             # Prior distribution for the Logistic intercept
beta[2]~dnorm(0,1.0E-6)             # Prior distribution for the gender effect
beta[3]~dnorm(0,1.0E-6)             # Prior distribution for the age effect
beta[4]~dunif(0,50)                 # Prior distribution for the Excess relative risk



}